Freenove ESP32-WROVER CAMボード【FNK0060 & FNK0060B】を試してみました【Arduino使用】

#include "esp_camera.h"
#include <SPI.h>
#include <Adafruit_GFX.h>    // Core graphics library
#include <Adafruit_ST7789.h> // Hardware-specific library for ST7789
#include <TJpg_Decoder.h>

// Pin definition for CAMERA_MODEL_WROVER_KIT
#define PWDN_GPIO_NUM -1
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 21
#define SIOD_GPIO_NUM 26
#define SIOC_GPIO_NUM 27

#define Y9_GPIO_NUM 35
#define Y8_GPIO_NUM 34
#define Y7_GPIO_NUM 39
#define Y6_GPIO_NUM 36
#define Y5_GPIO_NUM 19
#define Y4_GPIO_NUM 18
#define Y3_GPIO_NUM 5
#define Y2_GPIO_NUM 4
#define VSYNC_GPIO_NUM 25
#define HREF_GPIO_NUM 23
#define PCLK_GPIO_NUM 22

// Pin definition for TFT HSPI
#define TFT_SCLK 14
#define TFT_MISO -1
#define TFT_MOSI 13
#define TFT_CS 15 // Chip select control pin
#define TFT_DC 32 // Data Command control pin
#define TFT_RST 33

// Pin button
#define PIN_BTN 12

Adafruit_ST7789 tft = Adafruit_ST7789(&SPI, TFT_CS, TFT_DC, TFT_RST);

bool tft_output(int16_t x, int16_t y, uint16_t w, uint16_t h, uint16_t *bitmap)
{
  // Stop further decoding as image is running off bottom of screen
  if (y >= tft.height())
    return 0;
  tft.drawRGBBitmap(x, y, bitmap, w, h);
  // Return 1 to decode next block
  return 1;
}

void init_camera()
{
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG; // for streaming
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;

  // if PSRAM IC present, init with UXGA resolution and higher JPEG quality
  //                      for larger pre-allocated frame buffer.
  if (config.pixel_format == PIXFORMAT_JPEG)
  {
    if (psramFound())
    {
      config.jpeg_quality = 10;
      config.fb_count = 2;
      config.grab_mode = CAMERA_GRAB_LATEST;
    }
    else
    {
      // Limit the frame size when PSRAM is not available
      config.frame_size = FRAMESIZE_SVGA;
      config.fb_location = CAMERA_FB_IN_DRAM;
    }
  }
  else
  {
    // Best option for face detection/recognition
    config.frame_size = FRAMESIZE_QVGA;
#if CONFIG_IDF_TARGET_ESP32S3
    config.fb_count = 2;
#endif
  }

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK)
  {
    Serial.printf("Camera init failed with error 0x%x", err);
    for (;;)
      ;
  }

  sensor_t *s = esp_camera_sensor_get();
  // initial sensors are flipped vertically and colors are a bit saturated
  if (s->id.PID == OV3660_PID)
  {
    s->set_vflip(s, 1);       // flip it back
    s->set_brightness(s, 1);  // up the brightness just a bit
    s->set_saturation(s, -2); // lower the saturation
  }
  // drop down frame size for higher initial frame rate
  if (config.pixel_format == PIXFORMAT_JPEG)
  {
    s->set_framesize(s, FRAMESIZE_QVGA);
  }
}

void setup()
{
  Serial.begin(115200);
  Serial.println("ESP32-WROVER-CAM Picture");

  init_camera();

  // Use HSPI
  SPI.begin(TFT_SCLK, TFT_MISO, TFT_MOSI);
  // if the display has CS pin try with SPI_MODE0
  tft.init(240, 240); // Init ST7789 display 240x240 pixel
  tft.fillScreen(ST77XX_BLACK);

  TJpgDec.setJpgScale(1);
  // The decoder must be given the exact name of the rendering function above
  TJpgDec.setCallback(tft_output);

  pinMode(PIN_BTN, INPUT);
}

void take_picture()
{
  Serial.println("Taking picture..");
  camera_fb_t *fb = NULL;

  fb = esp_camera_fb_get();
  if (!fb)
  {
    Serial.println("Camera capture failed");
    return;
  }

  static uint16_t w = 0, h = 0;
  TJpgDec.getJpgSize(&w, &h, fb->buf, fb->len);
  Serial.print("- Width = ");
  Serial.print(fb->width);
  Serial.print(", height = ");
  Serial.println(fb->height);

  // Draw the image, top left at 0,0
  TJpgDec.drawJpg(0, 0, fb->buf, fb->len);

  // Free buffer
  esp_camera_fb_return(fb);
}

void loop()
{
  static int state = LOW;
  if (digitalRead(PIN_BTN) == HIGH)
  {
    Serial.println("Button pressed");
    take_picture();
    state = HIGH;
  }
  else if (digitalRead(PIN_BTN) == LOW && state == HIGH)
  {
    tft.fillScreen(ST77XX_BLACK);
    state = LOW;
  }

  delay(500);
}

  tft.init(240, 240, SPI_MODE2); // Init ST7789 display 240x240 pixel

  pinMode(PIN_BTN, INPUT_PULLDOWN);

#include "esp_camera.h"
#include <LovyanGFX.hpp>

// Pin definition for CAMERA_MODEL_WROVER_KIT
#define PWDN_GPIO_NUM -1
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 21
#define SIOD_GPIO_NUM 26
#define SIOC_GPIO_NUM 27

#define Y9_GPIO_NUM 35
#define Y8_GPIO_NUM 34
#define Y7_GPIO_NUM 39
#define Y6_GPIO_NUM 36
#define Y5_GPIO_NUM 19
#define Y4_GPIO_NUM 18
#define Y3_GPIO_NUM 5
#define Y2_GPIO_NUM 4
#define VSYNC_GPIO_NUM 25
#define HREF_GPIO_NUM 23
#define PCLK_GPIO_NUM 22

// Pin definition for TFT HSPI
#define TFT_SCLK 14
#define TFT_MISO -1
#define TFT_MOSI 13
#define TFT_CS 15  // Chip select control pin
#define TFT_DC 32  // Data Command control pin
#define TFT_RST 33

// Pin button
#define PIN_BTN 12

int32_t lcd_width;
int32_t lcd_height;
int32_t y;

// LCD表示画像の倍率
float zoom;

// カメラ画像フレームバッファ
camera_fb_t *fb;

// ST7789 1.3インチ CSなし
class LGFX : public lgfx::LGFX_Device {
  lgfx::Panel_ST7789 _panel_instance;
  lgfx::Bus_SPI _bus_instance;  // SPIバスのインスタンス

public:
  LGFX(void) {
    {                                     // バス制御の設定を行います。
      auto cfg = _bus_instance.config();  // バス設定用の構造体を取得します。

      // SPIバスの設定
      cfg.spi_host = SPI3_HOST;
      cfg.spi_mode = 0;           // SPI通信モードを設定 (0 ~ 3)
      cfg.freq_write = 40000000;  // 送信時のSPIクロック (最大80MHz, 80MHzを整数で割った値に丸められます)
      cfg.freq_read = 20000000;   // 受信時のSPIクロック

      //      cfg.spi_3wire  = true;        // 受信をMOSIピンで行う場合はtrueを設定
      //      cfg.use_lock   = true;        // トランザクションロックを使用する場合はtrueを設定
      cfg.dma_channel = SPI_DMA_CH_AUTO;  // 使用するDMAチャンネルを設定 (0=DMA不使用 / 1=1ch / 2=ch / SPI_DMA_CH_AUTO=自動設定)

      cfg.pin_sclk = TFT_SCLK;  // SPIのSCLKピン番号を設定
      cfg.pin_mosi = TFT_MOSI;  // SPIのMOSIピン番号を設定
      cfg.pin_miso = TFT_MISO;  // SPIのMISOピン番号を設定 (-1 = disable)
      cfg.pin_dc = TFT_DC;      // SPIのD/Cピン番号を設定  (-1 = disable)

      _bus_instance.config(cfg);               // 設定値をバスに反映します。
      _panel_instance.setBus(&_bus_instance);  // バスをパネルにセットします。
    }

    {                                       // 表示パネル制御の設定を行います。
      auto cfg = _panel_instance.config();  // 表示パネル設定用の構造体を取得します。

      cfg.pin_cs = -1;    // CSが接続されているピン番号   (-1 = disable)
      cfg.pin_rst = -1;   // RSTが接続されているピン番号  (-1 = disable)
      cfg.pin_busy = -1;  // BUSYが接続されているピン番号 (-1 = disable)

      cfg.panel_width = 240;   // 実際に表示可能な幅
      cfg.panel_height = 240;  // 実際に表示可能な高さ

      cfg.invert = true;  // パネルの明暗が反転してしまう場合 trueに設定
      // cfg.rgb_order = true; // パネルの赤と青が入れ替わってしまう場合 trueに設定

      _panel_instance.config(cfg);
    }

    setPanel(&_panel_instance);  // 使用するパネルをセットします。

    lgfx::pinMode(TFT_RST, lgfx::pin_mode_t::output);
    lgfx::pinMode(TFT_SCLK, lgfx::pin_mode_t::output);

    lgfx::gpio_lo(TFT_RST);
    lgfx::gpio_hi(TFT_SCLK);
    lgfx::gpio_hi(TFT_RST);
  }
};

static LGFX tft;

void init_camera() {
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG;  // for streaming
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;

  // if PSRAM IC present, init with UXGA resolution and higher JPEG quality
  //                      for larger pre-allocated frame buffer.
  if (config.pixel_format == PIXFORMAT_JPEG) {
    if (psramFound()) {
      config.jpeg_quality = 10;
      config.fb_count = 2;
      config.grab_mode = CAMERA_GRAB_LATEST;
    } else {
      // Limit the frame size when PSRAM is not available
      config.frame_size = FRAMESIZE_SVGA;
      config.fb_location = CAMERA_FB_IN_DRAM;
    }
  } else {
    // Best option for face detection/recognition
    config.frame_size = FRAMESIZE_QVGA;
#if CONFIG_IDF_TARGET_ESP32S3
    config.fb_count = 2;
#endif
  }

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    for (;;)
      ;
  }

  sensor_t *s = esp_camera_sensor_get();
  // initial sensors are flipped vertically and colors are a bit saturated
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1);        // flip it back
    s->set_brightness(s, 1);   // up the brightness just a bit
    s->set_saturation(s, -2);  // lower the saturation
  }
  // drop down frame size for higher initial frame rate
  if (config.pixel_format == PIXFORMAT_JPEG) {
    s->set_framesize(s, FRAMESIZE_QVGA);
  }
}

void setup() {
  Serial.begin(115200);
  Serial.println("ESP32-WROVER-CAM Picture");

  // スイッチの入力設定
  pinMode(PIN_BTN, INPUT_PULLDOWN);

  tft.init();
  // 画面回転はLCDに合わせて設定してください
  // tft.setRotation(1);

  lcd_width = tft.width();
  lcd_height = tft.height();

  // カメラ初期化
  init_camera();
  // カメラ画像の横幅を取得
  fb = esp_camera_fb_get();
  if (!fb) {
    Serial.println("Camera capture failed");
    // カメラ画像が取得できない場合は停止
    for (;;)
      yield();
  }
  // LCD画像の倍率をセット
  zoom = lcd_width / (float)fb->width;
  y = (lcd_height - fb->height * zoom) / 2;
}

void loop() {
  static int state = LOW;
  if (digitalRead(PIN_BTN) == HIGH) {
    // Serial.println("Button pressed");

    // フレームバッファ解放
    esp_camera_fb_return(fb);

    // カメラのフレームを取得
    fb = esp_camera_fb_get();
    if (!fb) {
      Serial.println("Camera capture failed");
      // カメラ画像が取得できない場合は停止
      for (;;)
        yield();
    }
    // Serial.println("Taking picture..");

    tft.drawJpg(fb->buf, fb->len, 0, y, lcd_width, lcd_height, 0, 0, zoom);

    state = HIGH;
  } else if (digitalRead(PIN_BTN) == LOW && state == HIGH) {
    tft.clear();
    state = LOW;
  }

  delay(100);
}

#include "SD_MMC.h"
#include <LovyanGFX.hpp>

#define SD_MMC_CMD 15  //Please do not modify it.
#define SD_MMC_CLK 14  //Please do not modify it.
#define SD_MMC_D0 2    //Please do not modify it.

// ESP32 for ST7789 1.3LCD
#define TFT_MISO -1
#define TFT_MOSI 13
#define TFT_SCLK 12
#define TFT_DC 32
#define TFT_RST 33

class LGFX : public lgfx::LGFX_Device {
  lgfx::Panel_ST7789 _panel_instance;
  lgfx::Bus_SPI _bus_instance;  // SPIバスのインスタンス

public:
  LGFX(void) {
    {                                     // バス制御の設定を行います。
      auto cfg = _bus_instance.config();  // バス設定用の構造体を取得します。

      // SPIバスの設定
      cfg.spi_host = SPI3_HOST;
      cfg.spi_mode = 0;           // SPI通信モードを設定 (0 ~ 3)
      cfg.freq_write = 40000000;  // 送信時のSPIクロック (最大80MHz, 80MHzを整数で割った値に丸められます)
      // cfg.freq_read = 20000000;   // 受信時のSPIクロック

      cfg.spi_3wire = true;               // 受信をMOSIピンで行う場合はtrueを設定
      cfg.use_lock = true;                // トランザクションロックを使用する場合はtrueを設定
      cfg.dma_channel = SPI_DMA_CH_AUTO;  // 使用するDMAチャンネルを設定 (0=DMA不使用 / 1=1ch / 2=ch / SPI_DMA_CH_AUTO=自動設定)

      cfg.pin_sclk = TFT_SCLK;  // SPIのSCLKピン番号を設定
      cfg.pin_mosi = TFT_MOSI;  // SPIのMOSIピン番号を設定
      cfg.pin_miso = TFT_MISO;  // SPIのMISOピン番号を設定 (-1 = disable)
      cfg.pin_dc = TFT_DC;      // SPIのD/Cピン番号を設定  (-1 = disable)

      _bus_instance.config(cfg);               // 設定値をバスに反映します。
      _panel_instance.setBus(&_bus_instance);  // バスをパネルにセットします。
    }

    {                                       // 表示パネル制御の設定を行います。
      auto cfg = _panel_instance.config();  // 表示パネル設定用の構造体を取得します。

      cfg.pin_cs = -1;    // CSが接続されているピン番号   (-1 = disable)
      cfg.pin_rst = -1;   // RSTが接続されているピン番号  (-1 = disable)
      cfg.pin_busy = -1;  // BUSYが接続されているピン番号 (-1 = disable)

      cfg.panel_width = 240;   // 実際に表示可能な幅
      cfg.panel_height = 240;  // 実際に表示可能な高さ

      cfg.readable = false;  // データ読出しが可能な場合 trueに設定
      cfg.invert = true;     // パネルの明暗が反転してしまう場合 trueに設定
      // cfg.rgb_order = true; // パネルの赤と青が入れ替わってしまう場合 trueに設定
      // cfg.bus_shared = true;

      _panel_instance.config(cfg);
    }
    setPanel(&_panel_instance);  // 使用するパネルをセットします。

    lgfx::pinMode(TFT_RST, lgfx::pin_mode_t::output);
    lgfx::pinMode(TFT_SCLK, lgfx::pin_mode_t::output);

    lgfx::gpio_lo(TFT_RST);
    lgfx::gpio_hi(TFT_SCLK);
    lgfx::gpio_hi(TFT_RST);
  }
};

const unsigned long displayDuration = 2000;  // Display time (2 seconds)

LGFX lcd;  // LGFX instance
std::vector<String> fileList;
int currentIndex = 0;
int32_t screenWidth;
int32_t screenHeight;

void initFileSystem() {
  // SDカードスロット初期化
  SD_MMC.setPins(SD_MMC_CLK, SD_MMC_CMD, SD_MMC_D0);
  if (!SD_MMC.begin("/sdcard", true)) {
    Serial.println("Card Mount Failed");
    for (;;) yield();
  }
}

void createFileList() {
  File root = SD_MMC.open("/");
  File file = root.openNextFile();

  while (file) {
    String filePath = file.path();
    if (!filePath.startsWith("/.") && (filePath.endsWith(".jpg") || filePath.endsWith(".png"))) {
      fileList.push_back(filePath);
    }
    file = root.openNextFile();
  }
  root.close();

  if (fileList.empty()) {
    Serial.println("No image files found in SD.");
    for (;;) yield();
  }
}

// Get JPEG image size
bool getJpgSize(File &file, int &width, int &height) {
  uint8_t data[5];
  file.read(data, 2);

  if (data[0] == 0xFF && data[1] == 0xD8) {
    while (file.read(data, 4) == 4) {
      if (data[0] == 0xFF && (data[1] >= 0xC0 && data[1] <= 0xC3)) {
        file.read(data, 5);
        height = data[1] << 8 | data[2];
        width = data[3] << 8 | data[4];
        return true;
      } else {
        uint16_t size = data[2] << 8 | data[3];
        file.seek(file.position() + size - 2);
      }
    }
  }
  return false;
}

// Get PNG image size
bool getPngSize(File &file, int &width, int &height) {
  uint8_t data[24];
  if (file.read(data, 24) == 24) {
    if (data[0] == 0x89 && data[1] == 0x50 && data[2] == 0x4E && data[3] == 0x47) {
      width = data[16] << 24 | data[17] << 16 | data[18] << 8 | data[19];
      height = data[20] << 24 | data[21] << 16 | data[22] << 8 | data[23];
      return true;
    }
  }
  return false;
}

void drawImage(const String &fileName) {
  File file = SD_MMC.open(fileName, FILE_READ);
  if (!file) {
    Serial.println("Failed to open file: " + fileName);
    return;
  }

  // Serial.printf("%s\n", fileName.c_str());
  int imgWidth = 0, imgHeight = 0;
  bool validImage = false;
  bool isJpg = false;

  // サイズ取得
  if (fileName.endsWith(".jpg")) {
    validImage = getJpgSize(file, imgWidth, imgHeight);
    isJpg = true;
  } else if (fileName.endsWith(".png")) {
    validImage = getPngSize(file, imgWidth, imgHeight);
  }

  if (!validImage) {
    file.close();
    Serial.println("Invalid or unsupported image format.");
    return;
  }

  // ファイル開始位置を戻す
  file.seek(0);

  // スケーリング
  float scaleX = static_cast<float>(screenWidth) / imgWidth;
  float scaleY = static_cast<float>(screenHeight) / imgHeight;
  float scale = min(scaleX, scaleY);

  // x座標 センタリング
  int32_t x = (screenWidth - imgWidth * scale) / 2;

  lcd.startWrite();
  lcd.clear();
  if (isJpg) {
    lcd.drawJpg(&file, x, 0, screenWidth, screenHeight, 0, 0, scale);
  } else {
    lcd.drawPng(&file, x, 0, screenWidth, screenHeight, 0, 0, scale);
  }
  lcd.endWrite();
  file.close();
}

void setup() {
  Serial.begin(115200);

  // LCD初期化
  lcd.init();

  screenWidth = lcd.width();
  screenHeight = lcd.height();

  // SDカードスロット初期化
  initFileSystem();
  // 画像ファイルリスト取得
  createFileList();
}

void loop() {
  // 画像を描画
  drawImage(fileList[currentIndex]);
  // 次の画像(インデックス)
  currentIndex = (currentIndex + 1) % fileList.size();
  delay(displayDuration);
}

#include "esp_camera.h"
#include "SD_MMC.h"
#include <LovyanGFX.hpp>

// Pin definition for CAMERA_MODEL_WROVER_KIT
#define PWDN_GPIO_NUM -1
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 21
#define SIOD_GPIO_NUM 26
#define SIOC_GPIO_NUM 27

#define Y9_GPIO_NUM 35
#define Y8_GPIO_NUM 34
#define Y7_GPIO_NUM 39
#define Y6_GPIO_NUM 36
#define Y5_GPIO_NUM 19
#define Y4_GPIO_NUM 18
#define Y3_GPIO_NUM 5
#define Y2_GPIO_NUM 4
#define VSYNC_GPIO_NUM 25
#define HREF_GPIO_NUM 23
#define PCLK_GPIO_NUM 22

// Pin definition for SD MMC
#define SD_MMC_CMD 15  //Please do not modify it.
#define SD_MMC_CLK 14  //Please do not modify it.
#define SD_MMC_D0 2    //Please do not modify it.

// Pin definition for TFT HSPI
// #define TFT_SCLK 14
#define TFT_MISO -1
#define TFT_MOSI 13
#define TFT_SCLK 12
// #define TFT_CS 15  // Chip select control pin
#define TFT_DC 32  // Data Command control pin
#define TFT_RST 33

// カメラ画像の更新間隔 (ミリ秒で指定) 500ミリ秒間隔
#define UPDATE_INTERVAL (500u)

// Shutter button
#define SHUTTER_BUTTON 0

int32_t lcd_width;
int32_t lcd_height;
int32_t y;

// LCD表示画像の倍率
float zoom;

// カメラ画像フレームバッファ
camera_fb_t* fb;

// シャッター
volatile bool shutter = false;

// ST7789 1.3インチ CSなし
class LGFX : public lgfx::LGFX_Device {
  lgfx::Panel_ST7789 _panel_instance;
  lgfx::Bus_SPI _bus_instance;  // SPIバスのインスタンス

public:
  LGFX(void) {
    {                                     // バス制御の設定を行います。
      auto cfg = _bus_instance.config();  // バス設定用の構造体を取得します。

      // SPIバスの設定
      cfg.spi_host = SPI3_HOST;
      cfg.spi_mode = 0;           // SPI通信モードを設定 (0 ~ 3)
      cfg.freq_write = 40000000;  // 送信時のSPIクロック (最大80MHz, 80MHzを整数で割った値に丸められます)
      // cfg.freq_read = 20000000;   // 受信時のSPIクロック

      cfg.spi_3wire = true;               // 受信をMOSIピンで行う場合はtrueを設定
      cfg.use_lock = true;                // トランザクションロックを使用する場合はtrueを設定
      cfg.dma_channel = SPI_DMA_CH_AUTO;  // 使用するDMAチャンネルを設定 (0=DMA不使用 / 1=1ch / 2=ch / SPI_DMA_CH_AUTO=自動設定)

      cfg.pin_sclk = TFT_SCLK;  // SPIのSCLKピン番号を設定
      cfg.pin_mosi = TFT_MOSI;  // SPIのMOSIピン番号を設定
      cfg.pin_miso = TFT_MISO;  // SPIのMISOピン番号を設定 (-1 = disable)
      cfg.pin_dc = TFT_DC;      // SPIのD/Cピン番号を設定  (-1 = disable)

      _bus_instance.config(cfg);               // 設定値をバスに反映します。
      _panel_instance.setBus(&_bus_instance);  // バスをパネルにセットします。
    }

    {                                       // 表示パネル制御の設定を行います。
      auto cfg = _panel_instance.config();  // 表示パネル設定用の構造体を取得します。

      cfg.pin_cs = -1;    // CSが接続されているピン番号   (-1 = disable)
      cfg.pin_rst = -1;   // RSTが接続されているピン番号  (-1 = disable)
      cfg.pin_busy = -1;  // BUSYが接続されているピン番号 (-1 = disable)

      cfg.panel_width = 240;   // 実際に表示可能な幅
      cfg.panel_height = 240;  // 実際に表示可能な高さ

      cfg.readable = false;  // データ読出しが可能な場合 trueに設定
      cfg.invert = true;     // パネルの明暗が反転してしまう場合 trueに設定
      // cfg.rgb_order = true; // パネルの赤と青が入れ替わってしまう場合 trueに設定
      // cfg.bus_shared = true;

      _panel_instance.config(cfg);
    }
    setPanel(&_panel_instance);  // 使用するパネルをセットします。

    lgfx::pinMode(TFT_RST, lgfx::pin_mode_t::output);
    lgfx::pinMode(TFT_SCLK, lgfx::pin_mode_t::output);

    lgfx::gpio_lo(TFT_RST);
    lgfx::gpio_hi(TFT_SCLK);
    lgfx::gpio_hi(TFT_RST);
  }
};

static LGFX lcd;

void init_camera() {
  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG;  // for streaming
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;

  // if PSRAM IC present, init with UXGA resolution and higher JPEG quality
  //                      for larger pre-allocated frame buffer.
  if (config.pixel_format == PIXFORMAT_JPEG) {
    if (psramFound()) {
      config.jpeg_quality = 10;
      config.fb_count = 2;
      config.grab_mode = CAMERA_GRAB_LATEST;
    } else {
      // Limit the frame size when PSRAM is not available
      config.frame_size = FRAMESIZE_SVGA;
      config.fb_location = CAMERA_FB_IN_DRAM;
    }
  } else {
    // Best option for face detection/recognition
    config.frame_size = FRAMESIZE_QVGA;
#if CONFIG_IDF_TARGET_ESP32S3
    config.fb_count = 2;
#endif
  }

  // camera init
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Camera init failed with error 0x%x", err);
    for (;;)
      yield();
  }

  sensor_t* s = esp_camera_sensor_get();
  // initial sensors are flipped vertically and colors are a bit saturated
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1);        // flip it back
    s->set_brightness(s, 1);   // up the brightness just a bit
    s->set_saturation(s, -2);  // lower the saturation
  }
  // drop down frame size for higher initial frame rate
  if (config.pixel_format == PIXFORMAT_JPEG) {
    s->set_framesize(s, FRAMESIZE_VGA);
  }
}

void sdmmcInit(void) {
  SD_MMC.setPins(SD_MMC_CLK, SD_MMC_CMD, SD_MMC_D0);
  if (!SD_MMC.begin("/sdcard", true)) {
    Serial.println("Card Mount Failed");
    for (;;) yield();
  }
  uint8_t cardType = SD_MMC.cardType();
  if (cardType == CARD_NONE) {
    Serial.println("No SD_MMC card attached");
    for (;;) yield();
  }
  Serial.print("SD_MMC Card Type: ");
  if (cardType == CARD_MMC) {
    Serial.println("MMC");
  } else if (cardType == CARD_SD) {
    Serial.println("SDSC");
  } else if (cardType == CARD_SDHC) {
    Serial.println("SDHC");
  } else {
    Serial.println("UNKNOWN");
  }
  uint64_t cardSize = SD_MMC.cardSize() / (1024 * 1024);
  Serial.printf("SD_MMC Card Size: %lluMB\n", cardSize);
  Serial.printf("Total space: %lluMB\r\n", SD_MMC.totalBytes() / (1024 * 1024));
  Serial.printf("Used space: %lluMB\r\n", SD_MMC.usedBytes() / (1024 * 1024));
}

void createDir(fs::FS& fs, const char* path) {
  Serial.printf("Creating Dir: %s\n", path);
  if (fs.mkdir(path)) {
    Serial.println("Dir created");
  } else {
    Serial.println("mkdir failed");
  }
}

int readFileNum(fs::FS& fs, const char* dirname) {
  File root = fs.open(dirname);
  if (!root) {
    Serial.println("Failed to open directory");
    return -1;
  }
  if (!root.isDirectory()) {
    Serial.println("Not a directory");
    return -1;
  }

  File file = root.openNextFile();
  int num = 0;
  while (file) {
    file = root.openNextFile();
    num++;
  }
  return num;
}

void writejpg(fs::FS& fs, const char* path, const uint8_t* buf, size_t size) {
  File file = fs.open(path, FILE_WRITE);
  if (!file) {
    Serial.println("Failed to open file for writing");
    return;
  }
  file.write(buf, size);
  file.close();
  Serial.printf("Saved file to path: %s\r\n", path);
}

void shutterTask(void* arg) {
  for (;;) {
    if (!shutter && digitalRead(SHUTTER_BUTTON) == LOW) {
      shutter = true;
    }
    yield();
  }
}

void setup() {
  Serial.begin(115200);
  Serial.println("ESP32-WROVER-CAM Picture");

  // シャッターボタン
  pinMode(SHUTTER_BUTTON, INPUT_PULLUP);

  // LCD初期化
  lcd.init();
  // 画面回転はLCDに合わせて設定してください
  lcd.setRotation(1);

  lcd_width = lcd.width();
  lcd_height = lcd.height();

  // カメラ初期化
  init_camera();
  // カメラ画像の横幅を取得
  fb = esp_camera_fb_get();
  if (!fb) {
    Serial.println("Camera capture failed");
    // カメラ画像が取得できない場合は停止
    for (;;)
      yield();
  }
  // LCD画像の倍率をセット
  zoom = lcd_width / (float)fb->width;
  y = (lcd_height - fb->height * zoom) / 2;

  // SDカード初期化
  sdmmcInit();
  createDir(SD_MMC, "/camera");

  //Start Shutter tasks
  xTaskCreateUniversal(shutterTask, "shutterTask", 8192, NULL, 1, NULL, CONFIG_ARDUINO_RUNNING_CORE);
}

void loop() {
  static auto last = millis();

  if (millis() - last > UPDATE_INTERVAL) {
    // フレームバッファ解放
    esp_camera_fb_return(fb);

    // カメラのフレームを取得
    fb = esp_camera_fb_get();
    if (!fb) {
      Serial.println("Camera capture failed");
      // カメラ画像が取得できない場合は停止
      for (;;)
        yield();
    }
    Serial.println("Taking picture..");

    lcd.drawJpg(fb->buf, fb->len, 0, y, lcd_width, lcd_height, 0, 0, zoom);

    last = millis();
  }
  if (shutter) {
    while (digitalRead(SHUTTER_BUTTON) == LOW) yield();
    if (fb != NULL) {
      int photo_index = readFileNum(SD_MMC, "/camera");
      if (photo_index != -1) {
        String path = "/camera/" + String(photo_index) + ".jpg";
        // グレイに塗りつぶし シャッターを表現
        lcd.clear(TFT_DARKGREY);
        Serial.println("camera shutter");

        // 画像保存
        writejpg(SD_MMC, path.c_str(), fb->buf, fb->len);
        // LCDをクリア
        lcd.clear(TFT_BLACK);

        shutter = false;
      }
    }
  }
}